Knowledge Graph

This tool provides access to information in the EHRI Portal as Linked Open Data (LOD).

Explore the data

This tool takes data hosted in the EHRI portal and offers it as a Knowledge Graph (KG). Here you can browse different EHRI's entities (e.g., country reports, archival institutions descriptions, archival descriptions, etc.) as linked data, and you can link to them from you own data.

This KG follows aligns the data to Records in Context Ontology (RiC-O) and uses schema.org and own EHRI properties for completion. This specific use and combination will become part of a future EHRI ontology.

As an ongoing effort to connect with other KGs in the LOD cloud, and to our partner's own efforts, the EHRI KG is now connected to:

CDEC person database: We connect the people mentioned in CDEC's description in the EHRI KG to their representation in CDEC's KG, so you can complete the data shown here.
DBpedia: We link countries and languages to their DBpedia counterparts, so you can explore more generic data about them.
Wikidata: As part of a previous strategy all camps and ghettos were uploaded to Wikidata and therefore linked with their corresponding Wikidata entities.

To start exploring the data you have several possibilities listed below:

Countries list: You can use our countries list to start browsing institutions and, where available, their collections
SPARQL examples: You can consult our SPARQL queries examples and adapt them to your needs.
SPARQL endpoint: You can test your own queries against our SPARQL endpoint

Countries list

The country reports constitute the main entry point to exploring the data in the EHRI portal. They offers an introduction to the Holocaust research and landscape in a certain country. Therefore, we propose that non-experts users start browsing this KG from one of the proposed countries in order to get an idea of the potential of this new tool. Below you can find a comprehensive list of the countries represented in the EHRI portal.

SPARQL examples

In order to show how data is organised and how data can be consulted we provide different examples of SPARQL queries. They cover simple queries, some aggregatres to obtain statistical data and some federated queries that query CDEC's and DBpedia's data to expand this KG possibilities.

Federated queries show the potential that semantic technologies can suposse for users. However, even though the federated queries exposed here are carefully selected, take into account that modifying and expanding them can derive into unexpected long computation times.

List countries and labels

Get institutions in a country

Get instantiations from NIOD

Get records from NIOD

Get "scope and content" information of records from Kazerne Dossin that have Dutch descriptions

Get records with the subject "Newspapers"

Number of records in a country

Number of records per institution in a country

Average of records per country

PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri:  <http://lod.ehri-project-test.eu/>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
SELECT ?country (AVG(?totalRecordByInstitution) as ?meanByCountry) WHERE {
	?country a rico:Place ;
			rico:containsOrContained ?institution .
		{
			SELECT ?institution (COUNT(?record) as ?totalRecordByInstitution) WHERE {
				?institution a rico:CorporateBody ;
					rico:isOrWasHolderOf ?instantiation .
				?instantiation a rico:Instantiation ;
					rico:isInstantiationOf ?record .
				?record a rico:Record .
			} GROUP BY ?institution
		}
		
} GROUP BY ?country

Number of records in countries with less than 100000 population (Federated query against DBpedia)

Statistics of records whose subject is or not a survivor (Federated query against CDEC)

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX fo: <http://www.w3.org/1999/XSL/Format#>
PREFIX db: <http://dbpedia.org/>
PREFIX dbp: <http://dbpedia.org/property/>
PREFIX rico: <https://www.ica.org/standards/RiC/ontology#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX schema: <http://schema.org/>
PREFIX rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX ehri:  <http://lod.ehri-project-test.eu/>
PREFIX ehri_institutions: <http://lod.ehri-project-test.eu/institutions/>
PREFIX ehri_units: <http://lod.ehri-project-test.eu/units/>
PREFIX ehri_countries: <http://lod.ehri-project-test.eu/countries/>
PREFIX bio-ext: <http://dati.cdec.it/lod/bio-ext/>
SELECT ?survivor (COUNT(?record) as ?recordCount) WHERE {
	ehri_institutions:it-002845 rico:isOrWasHolderOf ?instantiation .
	?instantiation rico:isInstantiationOf ?record .
	?record rico:hasOrHadSubject ?personEHRI .
	?personEHRI owl:sameAs ?person .
	SERVICE <http://lod.xdams.org/sparql> {
		?person a foaf:Person ;
		bio-ext:shoahSurvivor ?survivor .
	}
} GROUP BY ?survivor

Records mentioning people deported to Auschwitz (Federated query against CDEC)

SELECT ?record WHERE {
	ehri_institutions:it-002845 rico:isOrWasHolderOf ?instantiation .
	?instantiation rico:isInstantiationOf ?record .
	?record rico:hasOrHadSubject ?personEHRI .
	?personEHRI owl:sameAs ?person .
	SERVICE <http://lod.xdams.org/sparql> {
		?person a foaf:Person ;
				shoah:persecution ?persecution .
		?persecution shoah:toNaziCamp ?camp .
		?camp rdfs:label "Auschwitz" .
	}
}